Problem of the Week 1242

Pythagoras Leaves Flatland

Solution

I received solutions from Al Zimmermann, John Duncan, Joseph DeVincentis, David Stigant, and Jim Tilley. John observes that de Gua's theorem is easily proved by algebra, since area can be computed by a cross product. This is how to do it in Mathematica.

A = {a, 0, 0}; B = {0, b, 0}; CC = {0, 0, c};
Norm[(1/2)*Cross[B - A, CC - A]]^2 /. Abs -> Identity
Norm[Cross[A, B]/2]^2 + Norm[Cross[B, CC]/2]^2 + Norm[Cross[CC, A]/2]^2 /.  Abs -> Identity

(a^2 b^2)/4 + (a^2 c^2)/4 + (b^2 c^2)/4
(a^2 b^2)/4 + (a^2 c^2)/4 + (b^2 c^2)/4

Now, for the given problem, here are three integer solutions, the first two by Duncan (designated JD) and Zimmermann (AZ), and the last being one that I found (SW) using Mathematica's FindInstance command.

ptsJD = {{0, 0, 0}, {1, 0, 0}, {2, 2, 1}, {0, 1, 0}};
ptsAZ = {{2, 0, 5}, {0, 0, 4}, {0, 2, 6}, {6, 0, 1}};
ptsSW = {{0, 0, 0}, {2, 2, 2}, {1, 0, 0}, {0, 0, 1}};

areasJD = Area /@ Triangle /@ Subsets[ptsJD, {3}];
areasAZ = Area /@ Triangle /@ Subsets[ptsAZ, {3}];
areasSW = Area /@ Triangle /@ Subsets[ptsSW, {3}];
{Total[areasJD[[{1, 2, 3}]]^2] == areasJD[[4]]^2, 
 Total[areasAZ[[{1, 2, 3}]]^2] == areasAZ[[4]]^2, 
 Total[areasSW[[{1, 2, 3}]]^2] == areasSW[[4]]^2}

{True, True, True}

The preceding tells us that the Pythagorean condition holds for the three solutions. Next, we check that the tetrahedron is not a right tetrahedron. We can do this by checking that three dot products are not all 0. Here, we learn that Zimmermann's solution has no right triangle faces, while Duncan's and mine have one.

{ptsJD[[2]].ptsJD[[3]], ptsJD[[2]].ptsJD[[4]], ptsJD[[3]].ptsJD[[4]]}
{ptsAZ[[2]].ptsAZ[[3]], ptsAZ[[2]].ptsAZ[[4]], ptsAZ[[3]].ptsAZ[[4]]}
{ptsSW[[2]].ptsSW[[3]], ptsSW[[2]].ptsSW[[4]], ptsSW[[3]].ptsSW[[4]]}

{2, 0, 2}
{24, 4, 6}
{2, 2, 0}

Next, we look at the four face areas. We see that Zimmermann's solution has the nice property that these four areas are integers.

areasJD
areasAZ
areasSW

{Sqrt[5]/2, 1/2, Sqrt[5]/2, Sqrt[11]/2}
{3, 6, 6, 9}
{Sqrt[2], Sqrt[2], 1/2, Sqrt[17]/2}

Now take a look at the six sides for each example.

Apply[Norm[#1-#2]&,Subsets[ptsJD,{2}],{1}]
Apply[Norm[#1-#2]&,Subsets[ptsAZ,{2}],{1}]
Apply[Norm[#1-#2]&,Subsets[ptsSW,{2}],{1}]

{1,3,1,Sqrt[6],Sqrt[2],Sqrt[6]}
{Sqrt[5],3,4 Sqrt[2],2 Sqrt[2],3 Sqrt[5],Sqrt[65]}
{2 Sqrt[3],1,1,3,3,Sqrt[2]}

From this, we learn that my solution has integer lengths for four of the six sides.

Now we look at the volume. Duncan's has the smallest volume. Zimmermann's has integer volume.

Volume[Tetrahedron[ptsJD]]
Volume[Tetrahedron[ptsAZ]]
Volume[Tetrahedron[ptsSW]]

1/6
4
1/3

Finally, we look at all the coordinates, and see that Duncan's has the smallest total.

Total[Flatten[ptsJD]]
Total[Flatten[ptsAZ]]
Total[Flatten[ptsSW]]

7
26
8

So, take your pick.

Al Zimmermann observes that there is also a 3-D Law of Cosines. A stronger assertion than de Gua's Theorem, this result was discovered in 1997:

Lee, J. R. "The Law of Cosines in a Tetrahedron." J. Korea Soc. Math. Ed. Ser. B: Pure Appl. Math. 4, 1-6, 1997.

[Back to Problem 1242]

© Copyright 2017 Stan Wagon. Reproduced with permission.